0186817989
Missed from the src ceph PKGBUILD somewhere along the way, added now. Issue: https://github.com/bazaah/aur-ceph/issues/7 Reported-by: aur.archlinux.org/account/antage
78 lines
3.5 KiB
Bash
78 lines
3.5 KiB
Bash
# Maintainer: Paul Stemmet <aur@luxolus.com>
|
|
|
|
pkgbase='ceph-bin'
|
|
pkgname=('ceph-bin' 'ceph-libs-bin' 'ceph-mgr-bin')
|
|
pkgver=17.2.5
|
|
pkgrel=4
|
|
pkgdesc='Distributed, fault-tolerant storage platform delivering object, block, and file system'
|
|
arch=('x86_64')
|
|
url='https://ceph.com/'
|
|
license=('GPL')
|
|
options=('emptydirs')
|
|
_artifact=v${pkgver}-${pkgrel}
|
|
source=("ceph-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_linux_${arch}.tar.zstd"
|
|
"ceph-libs-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_libs_linux_${arch}.tar.zstd"
|
|
"ceph-mgr-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_mgr_linux_${arch}.tar.zstd")
|
|
sha512sums=('1771dd508a329a7a379b3023d6c538719eef29b3534d967e545a55f4e6cd5c84456bbf823ab91c394c90e64eb42213a1a28c96c8c1d632240e2f5415ba8401c0'
|
|
'ad068ef3c4e7dcfeafd18855450b2a1fa19bc22bc4036ba1ca32bbf97e44cebd54ba701e25b165b217448af5d35ba5f48cbadd3d7a6bf084bd17d4f54c400ac7'
|
|
'4e0cfe0c17a092aa320cc025a7aff9544c7f94c5bd80ab8de2498eb1a81235a620096fcada82301efce51d8d69b53500e65d7feb22fca91524972ef91413d7ae')
|
|
# Don't extract source archives
|
|
noextract=("${source[@]%%::*}")
|
|
|
|
|
|
package_ceph-libs-bin() {
|
|
depends=('boost-libs' 'curl' 'glibc' 'keyutils' 'libutil-linux' 'bzip2' 'lz4' 'nss'
|
|
'oath-toolkit' 'python' 'snappy' 'systemd-libs' 'fmt' 'cryptsetup'
|
|
'lua' 'librdkafka' 'libaio' 'gperftools' 'librabbitmq-c'
|
|
'python-prettytable' 'python-yaml' 'python-setuptools')
|
|
provides=("ceph-libs=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph-libs')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-libs-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
package_ceph-bin() {
|
|
depends=("ceph-libs=${pkgver}-${pkgrel}"
|
|
'boost-libs' 'curl' 'fuse3' 'fmt' 'glibc' 'gperftools' 'java-runtime'
|
|
'keyutils' 'libaio' 'libutil-linux' 'librdkafka' 'cryptsetup' 'libnl'
|
|
'ncurses'
|
|
'nss' 'oath-toolkit' 'python'
|
|
'snappy' 'sudo' 'systemd-libs' 'lua' 'gawk')
|
|
backup=('etc/logrotate.d/ceph'
|
|
'etc/udev/rules.d/50-ceph-rbd.rules'
|
|
'etc/sysctl.d/90-ceph-osd.conf'
|
|
'etc/sudoers.d/90-ceph')
|
|
optdepends=('smartmontools: disk monitoring via S.M.A.R.T'
|
|
'nvme-cli: disk monitoring for NVMe drives')
|
|
provides=("ceph=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
package_ceph-mgr-bin() {
|
|
depends=("ceph=${pkgver}-${pkgrel}" "ceph-libs=${pkgver}-${pkgrel}"
|
|
'bash' 'boost-libs' 'curl' 'gperftools' 'nss' 'fmt'
|
|
'python' 'python-cherrypy' 'python-pecan' 'python-pyjwt' 'python-more-itertools' 'python-routes'
|
|
'python-numpy' 'python-scipy' 'python-six' 'python-coverage' 'python-pytest' 'python-dateutil'
|
|
'python-prettytable' 'python-requests' 'python-pyopenssl' 'python-bcrypt' 'python-yaml'
|
|
'python-werkzeug' 'python-jinja')
|
|
optdepends=('python-influxdb: influx module'
|
|
'python-kubernetes: rook module'
|
|
'python-prometheus_client: prometheus module'
|
|
'python-remoto: ssh module')
|
|
provides=("ceph-mgr=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph-mgr')
|
|
options=('emptydirs' '!strip')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-mgr-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|