50 lines
2.2 KiB
Bash
50 lines
2.2 KiB
Bash
# Maintainer: Noel Jacob <noeljacob91 at gmail dot com>
|
|
# Contributor: thdxr (original PKGBUILD)
|
|
# Contributor: 37h4n (aarch64 support added by Ethan Reece <aur at ethanreece dot com>)
|
|
# Contributor: sh!zeeg (shizeeque@gmail.com) support for non-avx2 CPUs, shell completions.
|
|
pkgname=bun-bin
|
|
pkgver=1.0.19
|
|
pkgrel=1
|
|
pkgdesc="All-in-one JavaScript runtime built for speed, with bundler, transpiler, test runner, and package manager. Includes bunx, shell completions and support for baseline CPUs"
|
|
arch=('x86_64' 'aarch64')
|
|
url="https://github.com/oven-sh/bun"
|
|
license=('MIT')
|
|
provides=('bun')
|
|
conflicts=('bun')
|
|
sha256sums_x86_64=('111dd800a3e1990e6eee6bf6acddd858117d834158dfe44057c905d674a09346')
|
|
sha256sums_aarch64=('717c9c2f9963ed1f80f2b907fd12367dffdfc37c9c3a2bbcdf51d7993a32b7ad')
|
|
_baseline=''
|
|
_baseline_sha256sums='511c9bcdf6fda4d07f6ab0217d79bff0cb172ba25e860eaaacfe49acce959a91'
|
|
if [[ $CARCH == 'x86_64' && $(cat /proc/cpuinfo | grep avx2) = '' ]];then
|
|
_baseline='-baseline'
|
|
sha256sums_x86_64=($_baseline_sha256sums)
|
|
fi
|
|
source_x86_64=("bun-x64-${pkgver}.zip::https://github.com/oven-sh/bun/releases/download/bun-v${pkgver}/bun-linux-x64${_baseline}.zip")
|
|
source_aarch64=("bun-aarch64-${pkgver}.zip::https://github.com/oven-sh/bun/releases/download/bun-v${pkgver}/bun-linux-aarch64.zip")
|
|
build() {
|
|
if [ "${CARCH}" == "aarch64" ]; then
|
|
cd "bun-linux-aarch64"
|
|
else
|
|
cd "bun-linux-x64${_baseline}"
|
|
fi
|
|
install -dm755 "completions"
|
|
SHELL=zsh "./bun" completions > "completions/bun.zsh"
|
|
SHELL=bash "./bun" completions > "completions/bun.bash"
|
|
SHELL=fish "./bun" completions > "completions/bun.fish"
|
|
}
|
|
package() {
|
|
if [ "${CARCH}" == "aarch64" ]; then
|
|
cd "bun-linux-aarch64"
|
|
install -Dm755 "./bun-linux-aarch64/bun" "${pkgdir}/usr/bin/bun"
|
|
else
|
|
cd "bun-linux-x64${_baseline}"
|
|
install -Dm755 "./bun" "${pkgdir}/usr/bin/bun"
|
|
fi
|
|
# simlink as bunx as in the official install.sh
|
|
ln -s bun "${pkgdir}/usr/bin/bunx"
|
|
|
|
install -Dm644 completions/bun.zsh "${pkgdir}/usr/share/zsh/site-functions/_bun"
|
|
install -Dm644 completions/bun.bash "${pkgdir}/usr/share/bash-completion/completions/bun"
|
|
install -Dm644 completions/bun.fish "${pkgdir}/usr/share/fish/vendor_completions.d/bun.fish"
|
|
}
|