# Maintainer: Cabel <mxzcabel at tuta dot com>
# Contributor: metiis <aur at metiis dot com>
# Contributor: Julio Gutierrez <bubuntux at gmail dot com>
# Contributor: Martoko <mbastholm at gmail dot com>

pkgname=nordvpn-bin
pkgver=3.20.2
pkgrel=2
pkgdesc="NordVPN CLI tool for Linux"
arch=('x86_64' 'i686' 'armv7h' 'aarch64' 'armeabi')
url="https://nordvpn.com/download/linux/"
license=('GPL3')
depends=('libxml2')
provides=('nordvpn')
conflicts=('openvpn-nordvpn')
install=nordvpn-bin.install
source=("https://archive.archlinux.org/repos/2025/04/29/core/os/x86_64/libxml2-2.13.8-1-x86_64.pkg.tar.zst")
sha256sums=('2a1b0ab11ff213a57268d20fff183e3fd3e4ab9191aeed473de336b77bdfa6e1')

source_x86_64=("https://repo.nordvpn.com/deb/nordvpn/debian/pool/main/n/nordvpn/nordvpn_${pkgver//_/-}_amd64.deb")
source_i686=("https://repo.nordvpn.com/deb/nordvpn/debian/pool/main/n/nordvpn/nordvpn_${pkgver//_/-}_i386.deb")
source_armv7h=("https://repo.nordvpn.com/deb/nordvpn/debian/pool/main/n/nordvpn/nordvpn_${pkgver//_/-}_armhf.deb")
source_aarch64=("https://repo.nordvpn.com/deb/nordvpn/debian/pool/main/n/nordvpn/nordvpn_${pkgver//_/-}_arm64.deb")
source_armeabi=("https://repo.nordvpn.com/deb/nordvpn/debian/pool/main/n/nordvpn/nordvpn_${pkgver//_/-}_armel.deb")
sha256sums_x86_64=('d9e2d5af4690a4c848302ae4c8845c09a6d7735f7b189677d5597904d0fb0e2f')
sha256sums_i686=('9a41cc4f40281468e19e5c2c7254617fc0a3d35e2a5fb00b402bf25a3e0a6c3c')
sha256sums_armv7h=('b661801e363edaf928fdbc8120d243a67c6d0584461bba312076a2a0a8e69d4f')
sha256sums_aarch64=('85773be5cf911b778d9a03c2efd61a56ce43c5ea66cc8e3de6fb9466073964f6')
sha256sums_armeabi=('f74e491dd1a8e7025dc7e242a4f3d85bbb9d466420f105c06c69e513a1d15350')

package() {
    bsdtar -O -xf *.deb data.tar.gz | bsdtar -C "${pkgdir}" -xJf -

    mv "${pkgdir}/usr/sbin/nordvpnd" "${pkgdir}/usr/bin"
    rm -r "${pkgdir}/etc/init.d"
    rm -r "${pkgdir}/usr/sbin"
    echo "g nordvpn - -" | install -Dm644 /dev/stdin "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
  #-----------------------------------------------------------------
  # Bellow is a TEMPORARY fix for the missing libxml2.so.2 library
  # when upgrading the package to the version 2.14.2
  #-----------------------------------------------------------------
  # If you wish, you can instead downgrade all your packages
  # within a specific date:
   ## 1. Edit your /etc/pacman.d/mirrorlist
   ## 2. Include the following line:
    ### Server = https://archive.archlinux.org/repos/2025/04/29/$repo/os/$archive
   ## 3. Then you run:
    ### pacman -Syyuu
    ## (-uu is for downgrade)
  # done
  #-----------------------------------------------------------------
    tar -xvf libxml2-2.13.8-1-x86_64.pkg.tar.zst "usr/lib/libxml2.so.2.13.8"
    install -Dm 755 "usr/lib/libxml2.so.2.13.8" "${pkgdir}/usr/lib/nordvpn/libxml2.so.2"
}