Christopher Cooper
5f210293f0
When switching to the license page from the website and adding the checksum, I tried to check that it seemed to change infrequently. However, it does seem in practice to change relatively frequently, breaking builds. Most changes are relatively insubstantial, e.g. link destination changes. So removing the checksum seems pretty much fine. This file is not used in any load-bearing way, so there's no significant security implication.
48 lines
1.8 KiB
Bash
48 lines
1.8 KiB
Bash
# Maintainer: Christopher Cooper <christopher@cg505.com>
|
|
# Maintainer: Jérôme Poulin <jeromepoulin@gmail.com>
|
|
pkgname=claude-code
|
|
pkgver=2.1.107
|
|
pkgrel=2
|
|
pkgdesc="An agentic coding tool that lives in your terminal"
|
|
arch=('x86_64' 'aarch64')
|
|
url="https://github.com/anthropics/claude-code"
|
|
license=('LicenseRef-claude-code')
|
|
depends=('bash')
|
|
# Binary is a self-contained Bun executable with embedded JS/resources - stripping breaks it
|
|
options=('!strip')
|
|
optdepends=(
|
|
'git: allow Claude to use git'
|
|
'github-cli: interact with GitHub'
|
|
'glab: interact with GitLab'
|
|
'ripgrep: enhanced file search'
|
|
'tmux: agent team split panes'
|
|
'bubblewrap: sandboxing'
|
|
'socat: sandboxing'
|
|
)
|
|
|
|
# This bucket is used in the official install script at https://claude.ai/install.sh
|
|
# curl -fsSL https://claude.ai/install.sh | grep GCS_BUCKET
|
|
_gcs_bucket="https://storage.googleapis.com/claude-code-dist-86c565f3-f756-42ad-8dfa-d59b1c096819/claude-code-releases"
|
|
source=("cc-legal::https://code.claude.com/docs/en/legal-and-compliance.md")
|
|
source_x86_64=("claude-${pkgver}-x86_64::${_gcs_bucket}/${pkgver}/linux-x64/claude")
|
|
source_aarch64=("claude-${pkgver}-aarch64::${_gcs_bucket}/${pkgver}/linux-arm64/claude")
|
|
|
|
sha256sums=('SKIP')
|
|
sha256sums_x86_64=('8abe3909c55b3afafa8939d28c2cc2fcf73ba9424a46b4f435bbadda7e0eb00d')
|
|
sha256sums_aarch64=('b3f1d3acde0a247c67a93638208911dd2f676743d16cb3f9bd3987ffb3498a00')
|
|
|
|
package() {
|
|
install -Dm755 "${srcdir}/claude-${pkgver}-${CARCH}" "${pkgdir}/opt/claude-code/bin/claude"
|
|
|
|
# Create wrapper script to disable autoupdater
|
|
install -dm755 "${pkgdir}/usr/bin"
|
|
cat > "${pkgdir}/usr/bin/claude" << 'EOF'
|
|
#!/bin/sh
|
|
export DISABLE_AUTOUPDATER=1
|
|
exec /opt/claude-code/bin/claude "$@"
|
|
EOF
|
|
chmod 755 "${pkgdir}/usr/bin/claude"
|
|
|
|
install -Dm644 "${srcdir}/cc-legal" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|