fbdc6aafff
- Update pkgrel - Fix shasums - Regenerate .SRCINFO Also enforce pkgrel in downloaded packages, as otherwise we'll run into this problem of cached pkg archives corrupting shasums
72 lines
3.1 KiB
Bash
72 lines
3.1 KiB
Bash
# Maintainer: Paul Stemmet <aur@luxolus.com>
|
|
|
|
pkgbase='ceph-bin'
|
|
pkgname=('ceph-bin' 'ceph-libs-bin' 'ceph-mgr-bin')
|
|
pkgver=17.2.5
|
|
pkgrel=3
|
|
pkgdesc='Distributed, fault-tolerant storage platform delivering object, block, and file system'
|
|
arch=('x86_64')
|
|
url='https://ceph.com/'
|
|
license=('GPL')
|
|
options=('emptydirs')
|
|
_artifact=v${pkgver}-2
|
|
source=("ceph-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_linux_${arch}.tar.zstd"
|
|
"ceph-libs-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_libs_linux_${arch}.tar.zstd"
|
|
"ceph-mgr-bin-${pkgver}-${pkgrel}.tar.zst::https://github.com/bazaah/aur-ceph/releases/download/${_artifact}/ceph_mgr_linux_${arch}.tar.zstd")
|
|
sha512sums=('845cfd6ebff47f1179f5e2044346178cc0c7442f2d083b0015d959e523b81f9c2c09246d5eb1de4fb102c2118aba15ff3a67e385b251e6ca656a90d28e45334d'
|
|
'9ba7d32b77b64b8c202937dc67a65172603d892e19f68958bf134d8c55e55565ed36ecb7eeb8b8e19ab691fc8afb8f9dacfc6603ddf9b1d5242d2809c8b21902'
|
|
'18ee4f23d50ae3dd4724903485f0bea6c297c3476cbc4721c1a5d6c1f1041a448be697c81168f78d0a28cfa635cf50d6a7ba28faa735f282785f8fd301d3705a')
|
|
# Don't extract source archives
|
|
noextract=("${source[@]%%::*}")
|
|
|
|
|
|
package_ceph-libs-bin() {
|
|
depends=('boost-libs' 'curl' 'glibc' 'keyutils' 'libutil-linux' 'bzip2' 'lz4' 'nss'
|
|
'oath-toolkit' 'python' 'snappy' 'systemd-libs' 'fmt' 'cryptsetup'
|
|
'lua' 'librdkafka' 'libaio' 'gperftools'
|
|
'python-prettytable' 'python-yaml' 'python-setuptools')
|
|
provides=("ceph-libs=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph-libs')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-libs-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
package_ceph-bin() {
|
|
depends=("ceph-libs=${pkgver}-${pkgrel}"
|
|
'boost-libs' 'curl' 'fuse3' 'fmt' 'glibc' 'gperftools' 'java-runtime'
|
|
'keyutils' 'libaio' 'libutil-linux' 'librdkafka' 'cryptsetup' 'libnl'
|
|
'ncurses'
|
|
'nss' 'oath-toolkit' 'python'
|
|
'snappy' 'sudo' 'systemd-libs' 'lua' 'gawk')
|
|
provides=("ceph=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
package_ceph-mgr-bin() {
|
|
depends=("ceph=${pkgver}-${pkgrel}" "ceph-libs=${pkgver}-${pkgrel}"
|
|
'bash' 'boost-libs' 'curl' 'gperftools' 'nss' 'fmt'
|
|
'python' 'python-cherrypy' 'python-pecan' 'python-pyjwt' 'python-more-itertools'
|
|
'python-numpy' 'python-scipy' 'python-six' 'python-coverage' 'python-pytest' 'python-dateutil'
|
|
'python-prettytable' 'python-requests' 'python-pyopenssl' 'python-bcrypt' 'python-yaml'
|
|
'python-werkzeug' 'python-jinja')
|
|
optdepends=('python-influxdb: influx module'
|
|
'python-kubernetes: rook module'
|
|
'python-prometheus_client: prometheus module'
|
|
'python-remoto: ssh module')
|
|
provides=("ceph-mgr=${pkgver}-${pkgrel}")
|
|
conflicts=('ceph-mgr')
|
|
options=('emptydirs' '!strip')
|
|
|
|
cd "${srcdir}"
|
|
|
|
tar --exclude='.*' --zstd -xv -f ceph-mgr-bin-${pkgver}-${pkgrel}.tar.zst -C "${pkgdir}"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|